Learn more about MATLAB Builder NE

Magic Square Example (Visual Basic)

To create the component for this example, see the first several steps in Deploying a Component Using the Magic Square Example. After you build the MagicSquareComp component, you can build an application that accesses the component as follows.

1. For this example, the application is MagicSquareApp.vb.

   You can find MagicSquareApp.vb in:

   matlabroot\toolbox\dotnetbuilder\Examples\VS8\NET
     \MagicSquareExample\MagicSquareVBApp

   The program listing is as follows.

    MagicSquareApp.vb

   ' *******************************************************************************
   '
   ' MagicSquareApp.vb
   '
   ' This example demonstrates how to use MATLAB Builder NE to build a simple 
   ' component returning a magic square and how to convert MWNumericArray types
   ' to native .NET types.
   '
   ' Copyright 2001-2008 The MathWorks, Inc.
   '
   ' *******************************************************************************
   
   Imports System
   Imports System.Reflection
   Imports MathWorks.MATLAB.NET.Utility
   Imports MathWorks.MATLAB.NET.Arrays
   
   Imports MagicSquareComp
   
   Namespace MathWorks.Examples.MagicSquare
   
       ' <summary>
       ' The MagicSquareApp class computes a magic square of the user specified size.  
       ' </summary>
       ' <remarks>
       ' args[0] - a positive integer representing the array size.
       ' </remarks>
       Class MagicSquareApp
   
   #Region " MAIN "
   
           ' <summary>
           ' The main entry point for the application.
           ' </summary>
           Shared Sub Main(ByVal args() As String)
   
               Dim arraySize As MWNumericArray = Nothing
               Dim magicSquare As MWNumericArray = Nothing
   
               Try
                   ' Get user specified command line arguments or set default
                   If (0 <> args.Length) Then
                       arraySize = New MWNumericArray(Int32.Parse(args(0)), False)
                   Else
                       arraySize = New MWNumericArray(4, False)
                   End If
   
                   ' Create the magic square object
                   Dim magic As MagicSquareClass = New MagicSquareClass
   
                   ' Compute the magic square and print the result
                   magicSquare = magic.makesquare(arraySize)
   
                   Console.WriteLine("Magic square of order {0}{1}{2}{3}", arraySize, Chr(10), Chr(10), magicSquare)
   
                   ' Convert the magic square array to a two dimensional native double array
                   Dim nativeArray(,) As Double = CType(magicSquare.ToArray(MWArrayComponent.Real), Double(,))
   
                   Console.WriteLine("{0}Magic square as native array:{1}", Chr(10), Chr(10))
   
                   ' Display the array elements:
                   Dim index As Integer = arraySize.ToScalarInteger()
   
                   For i As Integer = 0 To index - 1
                       For j As Integer = 0 To index - 1
                           Console.WriteLine("Element({0},{1})= {2}", i, j, nativeArray(i, j))
                       Next j
                   Next i
   
                   Console.ReadLine() 'Wait for user to exit application
   
               Catch exception As Exception
   
                   Console.WriteLine("Error: {0}", exception)
   
               End Try
           End Sub
   #End Region
   
       End Class
   
   End Namespace
   

   The application you build from this source file does the following:

   • Lets you pass a dimension for the magic square from the command line.

   • Converts the dimension argument to a MATLAB integer scalar value.

   • Declares variables of type MWNumericArray to handle data required by the encapsulated makesquare function.

     Note   For complete reference information about the MWArray class hierarchy, see the MWArray Class Library Reference (available online only).

   • Creates an instance of the MagicSquare class named magic.

   • Calls the makesquare method, which belongs to the magic object. The makesquare method generates the magic square using the MATLAB magic function.

   • Displays the array elements on the command line.

2. Build the application using Visual Studio .NET.

   1. The MagicSquareVBApp folder contains a Visual Studio .NET project file for each example. Open the project in Visual Studio .NET for this example by double-clicking MagicSquareVBApp.vbproj in Windows Explorer.

   2. If necessary, add a reference to the MWArray component, which is matlabroot\dotnetbuilder\bin\architecture\framework_version
      \mwarray.dll.

   3. If necessary, add a reference to the MagicSquareComp component, which is in the distrib subfolder.

   4. Build and run the application in Visual Studio.NET.

Sample Applications (Microsoft Visual Basic .NET)

Create Plot Example (Visual Basic)

© 1984-2009- The MathWorks, Inc.    -   Site Help   -   Patents   -   Trademarks   -   Privacy Policy   -   Preventing Piracy   -   RSS